* Richard A. DeVenezia ;
* 6/22/01;
*
* Using the page dimension in tabulate to title each
* table created in a single Proc TABULATE invocation;


data fake;
  label title1="<font color='teal'>Example";
  retain title1 " of what you can do</font>";

  label title2="<I>You know,";
  retain title2 " like having a different title for each table statement</I>";

  do level1 = 'A', 'B';*, 'C';
    do level2 = 'X', 'Y', 'Z';
      do level3 = 'Sue', 'Sam', 'Sally';
        do i = 1 to 1+int(5*ranuni(0));
         measure1 = ranuni(0);
         measure2 = ranuni(0);
         measure3 = ranuni(0);
         output;
        end;
      end;
    end;
  end;
run;

title;
footnote;

options nocenter nonumber nodate;

ods html path='\\extreme\samples' body='ods-tabulate.html' style=sasweb stylesheet='./ods-tabulate.css';

footnote "<P>Powered by SAS <IMG SRC='http://support.sas.com/rnd/images/ico_base.gif' align=ABSMIDDLE></P>";

proc tabulate data=fake ;
  class level1-level3 title1 title2;
  var measure1-measure3;

  table title1
        , level1*level2
          , level3 ;

  table title2
        , level3
          , measure1*(N MEAN STD)
            measure2*(N MEAN STD)
            measure3*(N MEAN STD);
run;

ods html close;